#define buttonMode 18
#define buttonUp 19

#define CLK 5
#define LE 14
#define OE 15
#define SDI 6

bool mode = true;                   // 0 - время - 1 -  установка времени
byte register1 = B00000000;         // 00.0X  BGCDEFA
byte register2 = B00000000;         // 00.X0  BGCDEFA
byte register3 = B00000000;         // 0X.00  BGCDEFAP
byte register4 = B00000000;         // X0.00  BGCDEFA
bool blnk = false;                  // мигание цифрами при установке времени
//                   0           1         2         3           4          5          6         7           8         9
byte number[] = {B10111110, B10100000, B11011010, B11110010, B11100100, B01110110, B01111110, B10100010, B11111110, B11110110}; //BGCDEFAP
byte h, m, s;
bool setTime = false;             // 0 - установка минут, 1 - установка часов

void setup()
{
    h=m=s=0;
    pinMode(buttonMode, INPUT_PULLUP);
    pinMode(buttonUp, INPUT_PULLUP);
    pinMode(CLK, OUTPUT);
    pinMode(LE, OUTPUT);
    pinMode(OE, OUTPUT);
    pinMode(SDI, OUTPUT);
    digitalWrite(OE, LOW);
    TIMSK &=~(1<<OCIE2 | 1<< TOIE2);                      // Запрещаем прерывания таймера 2
    ASSR  = 1<<AS2;                                       // Включаем асинхронный режим
    TCNT2 = 0;
    TCCR2 = 5<<CS20;                                      // Предделитель на 128 на 32768 даст 256 тиков в секунду
    while(ASSR & (1<<TCN2UB | 1<<OCR2UB | TCR2UB));
    TIFR  |= 1<<OCF2 | 1<< TOV2;                          // Сбрасываем флаги прерываний, на всякий случай.
    TIMSK |= 1<< TOIE2;                                   // Разрешаем прерывание по переполнению
}


void loop()
{     
   if (mode)                                                                                          // Если режим установки времени, то ждем ввода
   {
     
      if (!digitalRead(buttonMode) && !setTime) { setTime = true; delay(200);}                        // перепрыгиваем на установку часов
      if (!digitalRead(buttonMode) &&  setTime) { setTime = false; mode = false; delay(200);}         // выходим из установки часов
      if (!setTime && !digitalRead(buttonUp)) { blnk=false; if(m>=59) m=0; else m++; delay(200); };   // устанавливаем минуты (отменяем мигание числами, на время ввода)
      if (setTime && !digitalRead(buttonUp)) { blnk=false; if(h>=23) h=0; else h++; delay(200); };    // устанавливаем часы (отменяем мигание числами, на время ввода)
                                                                                                      // p.s. отмена мигание работает не особо корректно, но вполне рабочий вариант
      registerSet();
   }
   else    if (!digitalRead(buttonMode) && !mode) { mode = true; delay(200); s=0;}                    // Если режим отображения времени, то ждем изменения режима

}

ISR(TIMER2_OVF_vect)            // Прерырвание по переполнению таймера 2 (срабатывает раз в секунду)
{
    if(!mode)                                       // Если режим отображения времени
    {
      s++;                                          // увеличиваем секунду
      f_time();                                     // показываем время
      if(blnk) blnk = false; else  blnk = true;     // мигаем точкой
    }
    else                                            // Если режим установки времени
    {
      if(blnk) blnk = false; else  blnk = true;     // Мигаем числами, которые устанавливаем
    }
}

void f_time()
{ 
  if(s>59) { m++; s=0; }
  if(m>59) { h++; m=0; }
  if(h>23) { h=0; }
  registerSet();
}

void registerSet()              // Записываем время в переменные
{
  if (mode && blnk && !setTime && digitalRead(buttonUp))    // Не мигаем числами, если мы нажимаем на кнопку buttonUp
  {
    register1 = register2 = 0;
  }
  else
  {
    register1 = number[m%10];
    register2 = number[m%100/10];
  }
  if (mode && blnk && setTime && digitalRead(buttonUp))    // Не мигаем числами, если мы нажимаем на кнопку buttonUp
  {
    register3 = register4 = 0;
  }
  else
  {
    register3 = number[h%10];
    register4 = number[h%100/10]; 
  }
 
  if(blnk && !mode)                                        // Мигаем точкой, если мы в режиме отображения времени
        bitWrite(register3, 0, 1);
      else bitWrite(register3, 0, 0);
 
  registerWrite();                                         // Отправляем данные на сдвиговые регистры
}

void registerWrite()            // Отображаем данные на индикаторах
{
   
  digitalWrite(LE, LOW);
  // "проталкиваем" байты в регистры
  shiftOut(SDI, CLK, MSBFIRST, register1);
  shiftOut(SDI, CLK, MSBFIRST, register2);
  shiftOut(SDI, CLK, MSBFIRST, register3);
  shiftOut(SDI, CLK, MSBFIRST, register4);
 
  // "защелкиваем" регистр, чтобы биты появились на выходах регистра
  digitalWrite(LE, HIGH);
 
}