Буквенно-цифровой плазменный дисплей 32x8

Дисплеи, датчики и прочие функциональные узлы, управляемые МК.
Ответить
SERJSOCHI
Первый раз сказал Мяу!
Сообщения: 20
Зарегистрирован: Сб май 19, 2018 13:49:28

Буквенно-цифровой плазменный дисплей 32x8

Сообщение SERJSOCHI »

Добрый день.

Тема посвящена обзору и подключению дисплея IEE ARGUS 03100-08-256N (ALPHANUMERIC PLASMA DISPLAY 32X8), а так же его вероятных аналогов:
  • OKAYA RU-32-8RDC1A
    OKAYA RU-32-8RDC1-2
    SIEMENS GWE:000000227033
Обзор IEE ARGUS 03100-08-256N.

Дисплей приобрёл у seriy (объявление).

Дисплей позволяет вывести предварительно записанные в знакогенератор символы, имеет буфер на 256 символов.
Разрешение дисплея: 32 столбца на 8 строк.
Требуемые напряжения питания: +150В (150мА), -12В (100мА), +5В (1А). Дисплей требователен к качеству питания.
Интерфейс подключения: IDCC-34MR.

Распиновка и предзаписанные символы:
Изображение Изображение

Принцип управления: установить управляющие пины в соответсттвующее состояние, задать начальный адрес на шине адреса А0..А7, записать адрес (AW), задать код символа на шине D0..D5, записать символ (CLOCK). Повторять последние два действия для вывода строки. Более подробно приведено в коде, ниже.

Дисплей состоит из 3 плат: плата плазменной панели, плата драйвера, плата управления.

Дисплей: вид спереди и сзади.
Изображение Изображение

Плазменная панель RDMD573208BR-c (NIC E44246 Togoshi TS-5, M-0001-3)
Изображение Изображение

Драйвер 05464-25118-02:
Изображение Изображение

Плата управления 05464-24435-04-e:
Изображение Изображение

Примеры работы с IEE ARGUS 03100-08-256N.

По параллельному интерфейсу, подключение к Arduino MEGA 2560.
Изображение
Код:
Спойлер

Код: Выделить всё

// ALPHANUMERIC PLASMA DISPLAY 32X8
// OKAYA RU-32-8RDC1A
// OKAYA RU-32-8RDC1-2
// IEE ARGUS 03100-08-256N    <- TESTED
// SIEMENS GWE:000000227033
//
// SERJSOCHI, 2024
//
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
// PARALLEL CONNECT TO ARDUINO MEGA 2560
//
//      APD_PIN01 GND (connect to Arduino GND)
//      APD_PIN02 GND (connect to Arduino GND)
//      APD_PIN03 GND (connect to Arduino GND)
//      APD_PIN04 GND (connect to Arduino GND)
//      APD_PIN05 +5V_1A (EXTERNAL POWER! DO NOT 5V POWER SUPPLY FROM ARDUINO!)
//      APD_PIN06 +5V_1A (EXTERNAL POWER! DO NOT 5V POWER SUPPLY FROM ARDUINO!)
#define APD_PIN07_READY 26
//      APD_PIN08 Not connected
#define APD_PIN09_CL 28
#define APD_PIN10_CS 29
#define APD_PIN11_WF 30
#define APD_PIN12_A1 31
#define APD_PIN13_A2 32
#define APD_PIN14_A3 33
#define APD_PIN15_A5 34
#define APD_PIN16_A0 35
#define APD_PIN17_A4 36
#define APD_PIN18_AW 37
#define APD_PIN19_A7 38
#define APD_PIN20_A6 39
#define APD_PIN21_D5 40
#define APD_PIN22_WR 41
#define APD_PIN23_BL 42
#define APD_PIN24_RS 43
#define APD_PIN25_D0 44
#define APD_PIN26_D1 45
#define APD_PIN27_D2 46
#define APD_PIN28_D3 47
#define APD_PIN29_UL 48
#define APD_PIN30_D4 49
//      APD_PIN31 -12V
//      APD_PIN32 -12V
//      APD_PIN33 No pin
//      APD_PIN34 +150V_150mA
//
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
// MAIN

void APD_gotoXY(unsigned char posX, unsigned char posY){
  if (posX > 31) posX = 31; 
  if (posY > 7) posY = 7;

  unsigned char newPos = posX + posY*32;
  
  digitalWrite(APD_PIN16_A0, bitRead(newPos, 0));
  digitalWrite(APD_PIN12_A1, bitRead(newPos, 1));
  digitalWrite(APD_PIN13_A2, bitRead(newPos, 2));
  digitalWrite(APD_PIN14_A3, bitRead(newPos, 3));
  digitalWrite(APD_PIN17_A4, bitRead(newPos, 4));
  digitalWrite(APD_PIN15_A5, bitRead(newPos, 5));
  digitalWrite(APD_PIN20_A6, bitRead(newPos, 6));
  digitalWrite(APD_PIN19_A7, bitRead(newPos, 7));
  
  digitalWrite(APD_PIN18_AW, LOW);
  digitalWrite(APD_PIN18_AW, HIGH);
}

void APD_writeChar(unsigned char APD_SYMBOL, boolean APD_UNDERLINE = 0) {
  if (APD_SYMBOL == '_') APD_UNDERLINE = 1;

  digitalWrite(APD_PIN25_D0, bitRead(APD_SYMBOL, 0));
  digitalWrite(APD_PIN26_D1, bitRead(APD_SYMBOL, 1));
  digitalWrite(APD_PIN27_D2, bitRead(APD_SYMBOL, 2));
  digitalWrite(APD_PIN28_D3, bitRead(APD_SYMBOL, 3));
  digitalWrite(APD_PIN30_D4, bitRead(APD_SYMBOL, 4));
  digitalWrite(APD_PIN21_D5, bitRead(APD_SYMBOL, 5));
  digitalWrite(APD_PIN29_UL, APD_UNDERLINE);
}

void APD_clearScreen(){
  digitalWrite(APD_PIN24_RS, LOW);
  delay(10);
  digitalWrite(APD_PIN24_RS, HIGH);
}

void APD_showChar(unsigned char APD_SYMBOL, boolean APD_UNDERLINE = 0){
    APD_writeChar(APD_SYMBOL, APD_UNDERLINE);
    digitalWrite(APD_PIN09_CL, HIGH);
    digitalWrite(APD_PIN09_CL, LOW);  
}

void APD_showString(String APD_STRING, boolean APD_UNDERLINE = 0, boolean wideFont = 1) {
  APD_STRING.toUpperCase();
  byte str_len = APD_STRING.length();
  byte arrayPointer = 0;

  digitalWrite(APD_PIN11_WF, wideFont);

  while (str_len)
  {
    APD_writeChar(APD_STRING[arrayPointer], APD_UNDERLINE);
    digitalWrite(APD_PIN09_CL, HIGH);
    digitalWrite(APD_PIN09_CL, LOW);
    --str_len;
    ++arrayPointer;
  }
}

void setup() {
  pinMode(APD_PIN07_READY, INPUT);
  pinMode(APD_PIN09_CL, OUTPUT);
  pinMode(APD_PIN10_CS, OUTPUT);
  pinMode(APD_PIN11_WF, OUTPUT);
  pinMode(APD_PIN12_A1, OUTPUT);
  pinMode(APD_PIN13_A2, OUTPUT);
  pinMode(APD_PIN14_A3, OUTPUT);
  pinMode(APD_PIN15_A5, OUTPUT);
  pinMode(APD_PIN16_A0, OUTPUT);
  pinMode(APD_PIN17_A4, OUTPUT);
  pinMode(APD_PIN18_AW, OUTPUT);
  pinMode(APD_PIN19_A7, OUTPUT);
  pinMode(APD_PIN20_A6, OUTPUT);
  pinMode(APD_PIN21_D5, OUTPUT);
  pinMode(APD_PIN22_WR, OUTPUT);
  pinMode(APD_PIN23_BL, OUTPUT);
  pinMode(APD_PIN24_RS, OUTPUT);
  pinMode(APD_PIN25_D0, OUTPUT);
  pinMode(APD_PIN26_D1, OUTPUT);
  pinMode(APD_PIN27_D2, OUTPUT);
  pinMode(APD_PIN28_D3, OUTPUT);
  pinMode(APD_PIN29_UL, OUTPUT);
  pinMode(APD_PIN30_D4, OUTPUT);    

  digitalWrite(APD_PIN09_CL, LOW);
  digitalWrite(APD_PIN10_CS, LOW);
  digitalWrite(APD_PIN11_WF, HIGH);
  digitalWrite(APD_PIN12_A1, LOW);
  digitalWrite(APD_PIN13_A2, LOW);
  digitalWrite(APD_PIN14_A3, LOW);
  digitalWrite(APD_PIN15_A5, LOW);
  digitalWrite(APD_PIN16_A0, LOW);
  digitalWrite(APD_PIN17_A4, LOW);
  digitalWrite(APD_PIN18_AW, HIGH);
  digitalWrite(APD_PIN19_A7, LOW);
  digitalWrite(APD_PIN20_A6, LOW);
  digitalWrite(APD_PIN21_D5, LOW);
  digitalWrite(APD_PIN22_WR, HIGH);
  digitalWrite(APD_PIN23_BL, HIGH);
  digitalWrite(APD_PIN24_RS, HIGH);
  digitalWrite(APD_PIN25_D0, LOW);
  digitalWrite(APD_PIN26_D1, LOW);
  digitalWrite(APD_PIN27_D2, LOW);
  digitalWrite(APD_PIN28_D3, LOW);
  digitalWrite(APD_PIN29_UL, LOW);
  digitalWrite(APD_PIN30_D4, LOW);

  APD_clearScreen();

  APD_gotoXY(0,0);
  APD_showString("ALPHANUMERIC PLASMA DISPLAY 32X8", 1);

  APD_gotoXY(0,1);
  APD_showString("PARALLEL CONNECT TO ARDUINO MEGA");

  APD_gotoXY(3,4);
  APD_showString("REGULAR and ");
  APD_showString("UNDERLINE", 1);
  APD_showString(" TEXT");

  APD_gotoXY(0,6);
  APD_showString("When string length more than 32,text continues on the next line.");

  APD_gotoXY(3,2);
  APD_showString("ABCDEFGHIJKLMNOPQRSTUVWXYZ");

  APD_gotoXY(2,3);
  APD_showString("@[\\]^_ !\"#$%&'()*+,-./:;<=>?");

  APD_gotoXY(11,5);
  APD_showString("0123456789");
}


void loop() {

}
По интерфейсу i2c через плату HW-061 на базе PCF8574, подключенной к Arduino.
Изображение Изображение
Код:
Спойлер

Код: Выделить всё

// ALPHANUMERIC PLASMA DISPLAY 32X8
// OKAYA RU-32-8RDC1A
// OKAYA RU-32-8RDC1-2
// IEE ARGUS 03100-08-256N    <- TESTED
// SIEMENS GWE:000000227033
//
// SERJSOCHI, 2024
//
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
// I2C CONNECT TO HW-061 PCF8574 MODULE (REMOVE JUMPER!)
//
//      APD_PIN01 GND (connect to Arduino GND)
//      APD_PIN02 GND (connect to Arduino GND)
//      APD_PIN03 GND (connect to Arduino GND)
//      APD_PIN04 GND (connect to Arduino GND)
//      APD_PIN05 +5V_1A (EXTERNAL POWER! DO NOT 5V POWER SUPPLY FROM ARDUINO!)
//      APD_PIN06 +5V_1A (EXTERNAL POWER! DO NOT 5V POWER SUPPLY FROM ARDUINO!)
//      APD_PIN07_READY
//      APD_PIN08 Not connected
#define APD_PIN09_CL P0
//      APD_PIN10_CS GND (connect to Arduino GND)
//      APD_PIN11_WF +5V_1A
//      APD_PIN12_A1 GND (connect to Arduino GND)
//      APD_PIN13_A2 GND (connect to Arduino GND)
//      APD_PIN14_A3 GND (connect to Arduino GND)
//      APD_PIN15_A5 GND (connect to Arduino GND)
//      APD_PIN16_A0 GND (connect to Arduino GND)
//      APD_PIN17_A4 GND (connect to Arduino GND)
#define APD_PIN18_AW P3
//      APD_PIN19_A7 GND (connect to Arduino GND)
//      APD_PIN20_A6 GND (connect to Arduino GND)
#define APD_PIN21_D5 P1
//      APD_PIN22_WR +5V_1A
//      APD_PIN23_BL +5V_1A
//      APD_PIN24_RS +5V_1A
#define APD_PIN25_D0 P4
#define APD_PIN26_D1 P2
#define APD_PIN27_D2 P6
#define APD_PIN28_D3 P5
//      APD_PIN29_UL GND (connect to Arduino GND)
#define APD_PIN30_D4 P7
//      APD_PIN31 -12V
//      APD_PIN32 -12V
//      APD_PIN33 No pin
//      APD_PIN34 +150V_150mA
//
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
// MAIN
#include "PCF8574.h" // PCF8574 library by Renzo Mischianti

PCF8574 pcf8574(0x27);

unsigned char APD_BUF_ARRAY[256];
unsigned char APD_BUF_POS = 0;
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

void APD_gotoXY(unsigned char posX, unsigned char posY){
  if (posX > 31) posX = 31; 
  if (posY > 7) posY = 7;

  APD_BUF_POS = posX + posY*32;
}

void APD_writeChar(unsigned char APD_SYMBOL) {
  pcf8574.digitalWrite(APD_PIN25_D0, bitRead(APD_SYMBOL, 0));
  pcf8574.digitalWrite(APD_PIN26_D1, bitRead(APD_SYMBOL, 1));
  pcf8574.digitalWrite(APD_PIN27_D2, bitRead(APD_SYMBOL, 2));
  pcf8574.digitalWrite(APD_PIN28_D3, bitRead(APD_SYMBOL, 3));
  pcf8574.digitalWrite(APD_PIN30_D4, bitRead(APD_SYMBOL, 4));
  pcf8574.digitalWrite(APD_PIN21_D5, bitRead(APD_SYMBOL, 5));

  pcf8574.digitalWrite(APD_PIN09_CL, LOW);
  pcf8574.digitalWrite(APD_PIN09_CL, HIGH); 
}

void APD_clearScreen(){
  for (int i = 0; i < 256; i++) {
  APD_BUF_ARRAY[i] = ' ';
  }
}

void APD_putChar(unsigned char APD_SYMBOL){
  APD_BUF_ARRAY[APD_BUF_POS] = APD_SYMBOL;
  APD_BUF_POS++;
}

void APD_sendBuf(){
  pcf8574.digitalWrite(APD_PIN18_AW, HIGH);
  pcf8574.digitalWrite(APD_PIN18_AW, LOW);

  for (int i = 0; i < 256; i++) {
  APD_writeChar(APD_BUF_ARRAY[i]);
  }
}

void APD_putString(String APD_STRING) {
  APD_STRING.toUpperCase();
  byte str_len = APD_STRING.length();
  byte arrayPointer = 0;

  while (str_len)
  {
    APD_putChar(APD_STRING[arrayPointer]);
    --str_len;
    ++arrayPointer;
  }
}

void setup() {
  pcf8574.pinMode(APD_PIN09_CL, OUTPUT);
  pcf8574.pinMode(APD_PIN18_AW, OUTPUT);
  pcf8574.pinMode(APD_PIN25_D0, OUTPUT);
  pcf8574.pinMode(APD_PIN26_D1, OUTPUT);
  pcf8574.pinMode(APD_PIN27_D2, OUTPUT);
  pcf8574.pinMode(APD_PIN28_D3, OUTPUT);
  pcf8574.pinMode(APD_PIN30_D4, OUTPUT);
  pcf8574.pinMode(APD_PIN21_D5, OUTPUT);

  pcf8574.begin();

  pcf8574.digitalWrite(APD_PIN09_CL, HIGH);
  pcf8574.digitalWrite(APD_PIN18_AW, LOW);
  pcf8574.digitalWrite(APD_PIN25_D0, LOW);
  pcf8574.digitalWrite(APD_PIN26_D1, LOW);
  pcf8574.digitalWrite(APD_PIN27_D2, LOW);
  pcf8574.digitalWrite(APD_PIN28_D3, LOW);
  pcf8574.digitalWrite(APD_PIN30_D4, LOW);
  pcf8574.digitalWrite(APD_PIN21_D5, LOW);

  APD_clearScreen();

  APD_gotoXY(0,0);
  APD_putString("ALPHANUMERIC PLASMA DISPLAY 32X8");

  APD_gotoXY(1,1);
  APD_putString("I2C CONNECT VIA HW-061 PCF8574");

  APD_gotoXY(7,4);
  APD_putString("REGULAR TEXT ");
  APD_putString("ONLY");

  APD_gotoXY(0,6);
  APD_putString("When string length more than 32,text continues on the next line.");

  APD_gotoXY(3,2);
  APD_putString("ABCDEFGHIJKLMNOPQRSTUVWXYZ");

  APD_gotoXY(2,3);
  APD_putString("@[\\]^_ !\"#$%&'()*+,-./:;<=>?");

  APD_gotoXY(11,5);
  APD_putString("0123456789");

  APD_sendBuf();
}


void loop() {

}
Не совсем остался доволен таким способом, так как нет возможности управлять подчёркиванием (не хватает одного пина), и у меня почему-то ощутимо греется PCF8574 (но за 24 часа непрерывной работы, микросхема не сгорела). Думаю, самым оптимальным будет управление через 74HC595, 8 пинов достаточно для полноценного управления.
Вернуться к началу
Реклама
Аватара пользователя
HardWareMan
Мучитель микросхем
Сообщения: 436
Зарегистрирован: Ср сен 02, 2015 07:47:20

Re: Буквенно-цифровой плазменный дисплей 32x8

Сообщение HardWareMan »

MM5241 является ПЗУшкой:
Изображение
Это потенциальная возможность заменить фонт. Вероятно, если отреверсить схему то появится возможность даже увеличить размер ПЗУ знакогенератора до полноценного КОИ7 или даже KOI8R/CP866/CP1251.
Репозиторий STM32: https://cloud.mail.ru/public/2i19/Y4w8kKEiZ
Актуальность репозитория: 22 апреля 2026 года
Если чего-то не хватает с сайта st.com - пишите, докачаю.
/!\ Обновлений для STM32PowerMon и STM32PowerMon-UCPD временно не будет.
Вернуться к началу
Реклама
SERJSOCHI
Первый раз сказал Мяу!
Сообщения: 20
Зарегистрирован: Сб май 19, 2018 13:49:28

Re: Буквенно-цифровой плазменный дисплей 32x8

Сообщение SERJSOCHI »

Подключение IEE ARGUS 03100-08-256N по интерфейсу SPI с помощью сдвигового регистра 74HC595N.
Изображение
Код:
Спойлер

Код: Выделить всё

// ALPHANUMERIC PLASMA DISPLAY 32X8
// OKAYA RU-32-8RDC1A
// OKAYA RU-32-8RDC1-2
// IEE ARGUS 03100-08-256N    <- TESTED
// SIEMENS GWE:000000227033
//
// SERJSOCHI, 2024
//
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
// SPI CONNECT VIA 74HC595
//
//      74HC595
#define HC595_PIN01_Q1 1 // bit 1
#define HC595_PIN02_Q2 2 // bit 2
#define HC595_PIN03_Q3 3 // bit 3
#define HC595_PIN04_Q4 4 // bit 4
#define HC595_PIN05_Q5 5 // bit 5
#define HC595_PIN06_Q6 6 // bit 6
#define HC595_PIN07_Q7 7 // bit 7
//      HC595_PIN08 GND (connect to Arduino GND)
//      HC595_PIN09_NQ7 Not connected
//      HC595_PIN10_MR +5V_1A
#define HC595_PIN11_SH 5 // arduino pin 5
#define HC595_PIN12_ST 6 // arduino pin 6
//      HC595_PIN13_OE GND (connect to Arduino GND)
#define HC595_PIN14_DS 7 // arduino pin 7
#define HC595_PIN15_Q0 0 // bit 0
//      HC595_PIN16  +5V_1A

//      Display
//      APD_PIN01 GND (connect to Arduino GND)
//      APD_PIN02 GND (connect to Arduino GND)
//      APD_PIN03 GND (connect to Arduino GND)
//      APD_PIN04 GND (connect to Arduino GND)
//      APD_PIN05 +5V_1A (EXTERNAL POWER! DO NOT 5V POWER SUPPLY FROM ARDUINO!)
//      APD_PIN06 +5V_1A (EXTERNAL POWER! DO NOT 5V POWER SUPPLY FROM ARDUINO!)
//      APD_PIN07_READY
//      APD_PIN08 Not connected
#define APD_PIN09_CL HC595_PIN07_Q7
//      APD_PIN10_CS GND (connect to Arduino GND)
//      APD_PIN11_WF +5V_1A
//      APD_PIN12_A1 GND (connect to Arduino GND)
//      APD_PIN13_A2 GND (connect to Arduino GND)
//      APD_PIN14_A3 GND (connect to Arduino GND)
//      APD_PIN15_A5 GND (connect to Arduino GND)
//      APD_PIN16_A0 GND (connect to Arduino GND)
//      APD_PIN17_A4 GND (connect to Arduino GND)
#define APD_PIN18_AW HC595_PIN06_Q6
//      APD_PIN19_A7 GND (connect to Arduino GND)
//      APD_PIN20_A6 GND (connect to Arduino GND)
#define APD_PIN21_D5 HC595_PIN05_Q5
//      APD_PIN22_WR +5V_1A
//      APD_PIN23_BL +5V_1A
//      APD_PIN24_RS +5V_1A
#define APD_PIN25_D0 HC595_PIN15_Q0
#define APD_PIN26_D1 HC595_PIN01_Q1
#define APD_PIN27_D2 HC595_PIN02_Q2
#define APD_PIN28_D3 HC595_PIN03_Q3
//      APD_PIN29_UL GND (connect to Arduino GND)
#define APD_PIN30_D4 HC595_PIN04_Q4
//      APD_PIN31 -12V
//      APD_PIN32 -12V
//      APD_PIN33 No pin
//      APD_PIN34 +150V_150mA
//
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
// MAIN
unsigned char APD_BUF_ARRAY[256];
unsigned char APD_BUF_POS = 0;
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

void APD_gotoXY(unsigned char posX, unsigned char posY){
  if (posX > 31) posX = 31; 
  if (posY > 7) posY = 7;

  APD_BUF_POS = posX + posY*32;
}

void APD_putChar(unsigned char APD_SYMBOL){
  APD_BUF_ARRAY[APD_BUF_POS] = APD_SYMBOL;
  APD_BUF_POS++;
}

void APD_putString(String APD_STRING) {
  APD_STRING.toUpperCase();
  byte str_len = APD_STRING.length();
  byte arrayPointer = 0;

  while (str_len)
  {
    APD_putChar(APD_STRING[arrayPointer]);
    --str_len;
    ++arrayPointer;
  }
}

void APD_clearScreen(){
  for (int i = 0; i < 256; i++) {
  APD_BUF_ARRAY[i] = ' ';
  }
}

void HC595_sendByte(unsigned char HC595_BYTE){
  digitalWrite(HC595_PIN12_ST, LOW);
  shiftOut(HC595_PIN14_DS, HC595_PIN11_SH, MSBFIRST, HC595_BYTE);   
  digitalWrite(HC595_PIN12_ST, HIGH);
}

void APD_sendBuf(){
  unsigned char APD_TMP_BYTE = 0;

  bitClear(APD_TMP_BYTE, APD_PIN18_AW);
  HC595_sendByte(APD_TMP_BYTE);   

  bitSet(APD_TMP_BYTE, APD_PIN18_AW);
  HC595_sendByte(APD_TMP_BYTE);  

  for (int i = 0; i < 256; i++) {
    APD_TMP_BYTE = APD_BUF_ARRAY[i];

    bitSet(APD_TMP_BYTE, APD_PIN18_AW);
    bitClear(APD_TMP_BYTE, APD_PIN09_CL);
    HC595_sendByte(APD_TMP_BYTE);

    bitSet(APD_TMP_BYTE, APD_PIN09_CL);
    HC595_sendByte(APD_TMP_BYTE);
  }
}

void setup() {
  pinMode(HC595_PIN11_SH, OUTPUT);
  pinMode(HC595_PIN12_ST, OUTPUT);
  pinMode(HC595_PIN14_DS, OUTPUT);

  APD_clearScreen();

  APD_gotoXY(0,0);
  APD_putString("ALPHANUMERIC PLASMA DISPLAY 32X8");

  APD_gotoXY(4,1);
  APD_putString("SPI CONNECT VIA 74HC595N");

  APD_gotoXY(7,4);
  APD_putString("REGULAR TEXT ");
  APD_putString("ONLY");

  APD_gotoXY(0,6);
  APD_putString("When string length more than 32,text continues on the next line.");

  APD_gotoXY(3,2);
  APD_putString("ABCDEFGHIJKLMNOPQRSTUVWXYZ");

  APD_gotoXY(2,3);
  APD_putString("@[\\]^_ !\"#$%&'()*+,-./:;<=>?");

  APD_gotoXY(11,5);
  APD_putString("0123456789");

  APD_sendBuf();
}

void loop() {

}
Вернуться к началу
Аватара пользователя
Jack_A
Друг Кота
Сообщения: 6317
Зарегистрирован: Вт апр 24, 2007 07:45:40
Откуда: Minsk

Re: Буквенно-цифровой плазменный дисплей 32x8

Сообщение Jack_A »

Очень красиво выглядит. Не для покупки ради, просто любопытно стало: почём такая красота? (можно в личку)
СпойлерПросто глянул историю продавца - вроде как цены у него выше_крышные.
Изображение
Вернуться к началу
Реклама
Эиком - электронные компоненты и радиодетали
Ответить

Вернуться в «Периферия»