Форум РадиоКот

Код: Выделить всё

If OpenLibrary(1, "inpout32.dll")=0  ; Открываем библиотеку inpout32.dll
  MessageRequester("", "Нет "+Chr(34)+"inpout32.dll"+Chr(34)+"", 64)
  End ; Завершение работы программы
EndIf

Prototype Out32(Address, Value)   ; Дакларация функции Out32 из inpout32.dll
  Global Out_LPT.Out32=GetFunction(1,"Out32")
   
Procedure SendLPT1()  ; Процедура передачи данных в LPT1
Out.c=0
For i=8 To 1 Step -1    ; В цикле сканируются "флажки" (CheckBoxGadget) отвечающие за пины порта
  If GetGadgetState(i)=1  ; Определяем состояние "флажка"
    Out | 1                   ; Операция "Логическое ИЛИ"
  Else
    Out & %11111110       ; Операция "Логическое И"
  EndIf
  If i>1
    Out << 1                 ; Сдвиг переменной на 1 бит влево
  EndIf
Next i         
Out_LPT($378, Out)         ; Данные в LPT1
EndProcedure
               ; Открываем окно
OpenWindow(0,0,0,120,240,"lpt Pin", #PB_Window_MinimizeGadget|#PB_Window_ScreenCentered|#PB_Window_Invisible)  
  Frame3DGadget(#PB_Any,20,10,80,180,"Pins")
  y=28
  For i=1 To 8
    CheckBoxGadget(i,36,y,50,16,"Pin "+Str(i)) ; "флажки"
    y+20
  Next i
  ButtonGadget(9,6,210,110,24,"Отправить в LPT 1") ; Экранная кнопка
HideWindow(0,0)   ; Отображение окна на экране

Repeat         ; Главный (оконный) цикл программы "Repeat - Until"
   Event=WaitWindowEvent()  ; Идентификатор события
   If Event=#PB_Event_Gadget ; Произошло событие в гаджете
     Gadget=EventGadget()    ; ID гаджета, в котором произошло событие
     If Gadget=9             ; Обнаруден клик по экранной кнопке
       SendLPT1()            ; Процедура передачи информации по порт LPT1
     EndIf
   EndIf
Until Event=#PB_Event_CloseWindow ; Когда закрывают окно, цикл будет прерван и прога завершит работу

Код: Выделить всё

|    in1   in2   out1
|---[ ]---[/]---( )
|   out1  in3   out2
|---[ ]---[ ]---( )
|

Код: Выделить всё

; Для компиляции нужна библиотека HID_Lib
; http://pure-basic.narod.ru/libs.html#HID_Lib
#USB_PID=$1  ; USB идентификаторы устройства
#USB_VID=$1234
 
Procedure Send_USB_HID()  ; Процедура передачи данных в USB HID устройство
Out.c=0          ; Переменная (один байт)
Dim Buffer.c(1)  ; Массив однобайтных переменных

For i=8 To 1 Step -1     ; В цикле сканируются "флажки" (CheckBoxGadget) отвечающие за пины порта
  If GetGadgetState(i)=1  ; Определяем состояние "флажка"
    Out | 1               ; Операция "Логическое ИЛИ"
  Else
    Out & %11111110       ; Операция "Логическое И"
  EndIf
  If i>1
    Out << 1              ; Сдвиг переменной на 1 бит влево
  EndIf
Next i         

 HID_Handle=HID_Lib_OpenDevice(#USB_PID, #USB_VID) ; Открываем USB HID устройство
 If HID_Handle     ; Успешно получен доступ к устройству
   Buffer(0)=0
   Buffer(1)=Out  ; Копирование данных из переменной в массив
   HID_Lib_WriteDevice(HID_Handle, @Buffer(), 2) ; Передача данных HID устройству
   HID_Lib_CloseDevice(HID_Handle)               ; Закрытие доступа к устройству
 Else
   MessageRequester("PID = 1; VID = 1234 H", "Нет требуемого HID устройства!", 16)
 EndIf
EndProcedure
               ; Открываем окно
OpenWindow(0,0,0,120,240,"HID", #PB_Window_MinimizeGadget|#PB_Window_ScreenCentered|#PB_Window_Invisible)  
  Frame3DGadget(#PB_Any,20,10,80,180,"Биты")
  y=28
  For i=1 To 8
    CheckBoxGadget(i,30,y,60,16,"Бит № "+Str(i)) ; "флажки"
    y+20
  Next i
  ButtonGadget(9,2,210,116,24,"Отправить в USB HID") ; Экранная кнопка
HideWindow(0,0)   ; Отображение окна на экране

Repeat         ; Главный (оконный) цикл программы "Repeat - Until"
   Event=WaitWindowEvent()  ; Идентификатор события
   If Event=#PB_Event_Gadget ; Произошло событие в гаджете
     Gadget=EventGadget()    ; ID гаджета, в котором произошло событие
     If Gadget=9             ; Обнаруден клик по экранной кнопке
       Send_USB_HID()            ; Процедура передачи информации USB HID устройствe
     EndIf
   EndIf
Until Event=#PB_Event_CloseWindow ; Когда закрывают окно, цикл будет прерван и прога завершит работу

Код: Выделить всё

 HID_Handle=HID_Lib_OpenDevice(#USB_PID, #USB_VID) ; Открываем USB HID устройство
 If HID_Handle     ; Успешно получен доступ к устройству
   Buffer(0)=0
   Buffer(1)=Out  ; Копирование данных из переменной в массив
   HID_Lib_WriteDevice(HID_Handle, @Buffer(), 2) ; Передача данных HID устройству
   HID_Lib_CloseDevice(HID_Handle)               ; Закрытие доступа к устройству
 Else
   MessageRequester("PID = 1; VID = 1234 H", "Нет требуемого HID устройства!", 16)
 EndIf